interface
  ...
var
  Cap   : array of array of SmallInt;  // данные из половины входного буфера
  CapIs : boolean = false;             // наличие необработанных данных в Cap
  ...

implementation

var
  Events     : array[0..3] of THandle;             // дескрипторы событий для вывода и ввода
  EventsPos  : array[0..1] of TDSBPositionNotify;  // позиции уведомлений воспроизведения
  CEventsPos : array[0..1] of TDSBPositionNotify;  // позиции уведомлений ввода
  blank      : boolean;  // буфер еще пуст (первое событие после запуска)
  ...

procedure PlayExecute;
var
  evt    : DWORD;  //  номер события
  offset : DWORD;  //  положение начала сегмента относительно начала буфера
begin
  while true do begin
    //  ожидание события
    evt:= WaitForMultipleObjects(4, PWOHandleArray(@Events), false, INFINITE);
    //  определение индекса события
    evt:= evt - WAIT_OBJECT_0;
    //  произошло ли событие вывода иди ввода?
    if evt < 2 then begin
      //  событие вывода: определение заполняемой половины буфера
      if evt = 0
        then offset:= EventsPos[1].dwOffset   // заполняется вторая половина
        else offset:= 0;                      // заполняется первая половина
      //--------------------------------------------------
      FillBufferSegment(offset, EventsPos[1].dwOffset);
      //--------------------------------------------------
    end
    else begin
      //  событие ввода
      if blank then begin // сразу после старта буфер ещё пуст
        blank:= false;
        Continue;
      end;
      if CapIs then   // предыдущие данные еще не обработаны
        Continue;
      evt:= evt - 2;
      //  определение копируемой половины буфера
      if evt = 0
        then offset:= CEventsPos[1].dwOffset  // копируется вторая половина
        else offset:= 0;                      // копируется первая половина
      //--------------------------------------------------
      ReadBufferSegment(offset, СEventsPos[1].dwOffset);
      CapIs:= true;
      //------------------------------------------------------
    end;
  end;
end;

interface
  ...
var
  Cap   : array of array of SmallInt;  // данные из половины входного буфера
  CapIs : boolean = false;             // в Cap имеются необработанные данные
  ...

implementation

var
  //  формат буфера
  WFX : TWaveFormatEx =
    ( wFormatTag      : WAVE_FORMAT_PCM;        // тип формата
      nChannels       : 2;                      // количество каналов
      nSamplesPerSec  : 44100;                  // частота дискретизации
      nAvgBytesPerSec : 44100 * 2 * (16 div 8); // количество байтов в секунду (nBlockAlign * nSamplesPerSec)
      nBlockAlign     : 2 * (16 div 8);         // размер минимального блока данных в байтах
      wBitsPerSample  : 16;                     // количество бит на выборку (8, 16, ...)
      cbSize          : 0 );                    // для DirectSound всегда 0
  ...

procedure ReadBufferSegment(offset, l : DWORD);
  // offset, l - положение и длина в байтах получаемого сегмента буфера
var
  ad1, ad2 : pointer;  // адес сегмента буфера
  l1, l2   : DWORD;    // длина сегмента буфера в байтах
  i,j : DWORD;
  ls  : DWORD;         // длина сегмента буфера в минимальных блоках данных
begin
  //  блокирование буфера
  ad1:= nil;
  ad2:= nil;
  hr:= DSCB.Lock(offset, l, @ad1, @l1, @ad2, @l2, 0);
  if failed(hr) then begin
    ShowMessage('Ошибка при блокировании входного звукового буфера');
    halt;
  end;
  //--- копирование сегмента в массив Cap ---
  if not Assigned(Cap) or (Length(Cap) <> WFX.nChannels) then
    SetLength(Cap, WFX.nChannels);
  ls:= l1 div WFX.nBlockAlign;
  for j:=0 to WFX.nChannels-1 do begin
    if not Assigned(Cap[j]) or (Length(Cap[j]) <> ls) then
      SetLength(Cap[j], ls);
    for i:=0 to ls-1 do
      Cap[j,i]:= PSmallInt(DWORD(ad1) + i*WFX.nBlockAlign + 2*j)^;
  end;
  //  разблокирование буфера
  hr := DSCB.UnLock(ad1, l1, ad2, l2);
  if failed(hr) then begin
    ShowMessage('Ошибка при разблокировании входного звукового буфера');
    halt;
  end;
end;